一个启动盘Autoexec.bat的注释(2008-06-04 12:24:47)
标签：dos bat 杂谈 
分类：电脑知识
看到有人问一个批处理文件每条命令是做什么用的，随手简单写了一下，没有详细到每条命令都写注释，相信你能明白原因，嘿嘿~~~，算是对DOS新手的入门训练吧。这个批处理写的并不太好，但用来做一个标准的DOS启动盘是足够了。
注释在每一行命令的上面，以::开头
:: 关闭命令回显，执行时不显示每条命令的命令行，@表示本行也不显示
@ECHO OFF
:: 设置DIR命令的环境变量参数，使其默认列表时排序
SET DIRCMD=/O
:: 设置环境变量（虚拟盘的盘符）ramd为z:
set ramd=z:批处理文件怎么做
:: 运行A盘的虚拟磁盘程序生成2M的虚拟磁盘在Z:盘
a:\xmsdsk 2048 %ramd% /y /t
:: 显示换行
echo.
:: 显示Preparing base files to drive Z: ...
echo Preparing base files to drive Z: ...
echo.
:: 建立z:\bin目录
mkdir %ramd%\bin
:: 建立z:\temp目录
mkdir %ramd%\temp
:: 设置环境变量tmp、temp为z:\temp
set tmp=%ramd%\temp
set temp=%ramd%\temp
:: 设置搜索路径path
set path=%ramd%\bin
:: 复制文件a:\command到z:\，>nul表示将命令执行结果输出到空设备，即不显示命令执行结果
copy a:\command %ramd%\ >nul
:: 设置环境变量comspec为z:\command，这个变量用来指定系统使用的command的位置
set comspec=%ramd%\command
:: 继续复制程序到虚拟磁盘
copy a:\ %ramd%\bin >nul
copy a:\device %ramd%\bin >nul
:: 解压缩a:\ebd.cab到z:\bin
extract /y /l %ramd%\bin /e a:\ebd.cab >nul
:: 调入鼠标驱动, lh表示调入高端内存
lh mouse >nul
:: 调入doskey
lh doskey >nul
:: 清除屏幕显示
cls
:: 显示提示信息
echo Extracting device driver(s)...
mkdir %ramd%\device
extract /y /l %ramd%\device /e a:\cdrom.cab >nul
:: 用device命令调入光驱驱动
device %ramd%\device\vide-cdd.SYS /D:MSCD000
cls
echo.
echo Preparing to start your computer.
echo This may take a few minutes.
echo.
:: 运行光驱接口程序，例光驱可用
lh mscdex /D:MSCD000
:: 调入磁盘缓存程序smartdrv
lh smartdrv
:: 调用findcd.bat批处理文件，应该是用来查光驱给分配到哪个盘符了
call findcd.bat
echo.
echo The diagnostic tools were successfully loaded to drive Z:.
echo.
:: END标签
:END
:: 将当前盘切换为Z:
%ramd%
:: 调用gcdrom.bat，不知道这个批处理是做什么用的。
call gcdrom.bat

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。