ExcelVBA之传递参数给⼀⼦程序以及如何将值从⼦程序传递
回给主调过程
当你⼤VBA程序得越来越⼤，要很好地维护这么多的代码⾏是很困难的。要让你的程序容易编写、理解和改变，你就应该使⽤井井有条的结构化程序。你只要简单地将⼤问题分成⼀些可以同时执⾏的⼩问题就⾏。在VBA中，你可以通过创建⼀个主过程和⼀个或多个⼦过程来实现它。因为主过程和⼦过程都是⼦程序下⾯的例⼦显⽰过程AboutUser。该过程要求⽤户姓和名，并且将姓和名从全名中分离出来。最后的语句显⽰⽤户的姓，随后是逗号和名。你再读下去，该过程将被分割成⼏个任务，以⽰范使⽤主过程，⼦过程和函数的概念。
Sub AboutUser()
Dim fullName As String
Dim firstName As String
Dim lastName As String
Dim space As Integer
'get input from user 从⽤户获取信息
fullName = InputBox("Enter first and last name:")
'get first and last name strings 获得姓和名字符串
space = InStr(fullName, " ")
firstName = Left(fullName, space - 1)
lastName = Right(fullName, Len(fullName) - space)
'display last name, first name 显⽰姓和名
MsgBox lastName & ", " & firstName
End Sub
主过程：
Sub AboutUserMaster()
Dim first As String, last As String, full As String
Call GetUserName(full)
first = GetFirst(full)
last = GetLast(full)
Call DisplayLastFirst(first, last)
End Sub
上⾯显⽰的主过程通过调⽤适当的⼦程序和函数来控制程序的主流程。该主过程以变量⽣命开始，第⼀条语句Call GetUserName (full)调⽤⼦过程GetUserName并且传递给⼀参数——变量full的内容。
因为变量在执⾏调⽤语句之前没有赋与任何值，所以它的值是⼀个空字符串（“ ”）。注意，⼦过程的名称在Call之后。尽管你在调⽤过程时并没有要求使⽤关键字Call，但是，你在调⽤⼀个需要参数的过程时就必须使⽤它。参数列表必须包括在括号⾥⾯。
⼦过程：
Sub GetUserName(fullName As String)
fullName = InputBox("Enter first and last name:")
End Sub
过程GetUserName⽰范了两个⾮常重要的VB编程概念：如何传递参数给⼀⼦程序以及如何将值从⼦程序传递回给主调过程。
在主过程（见第⼆步）中，你调⽤了过程GetUserName，并且将其作为⼀参数传递：变量full。该变量被参数fullName接收，该参数⼦过程GetUserName的Sub语句⾥声明了。因为在VB调⽤⼦过程GetUserName的时候，变量full包含⼀空字符串，参数fullName同样也接收了这个空字符串。当VB显⽰对话框并且获得⽤户的姓名时，这个姓名将赋给参数fullName。赋给参数的值被传递回给⼦过程执⾏后的匹配参数。因此，当VB返回主过程时，变量full就回包含⽤户的姓名。
传递给⼦过程的⾃变量将被其参数接收。注意，参数名称（fullName）后⾯紧跟着数据类型的声明（AsString）。虽然，参数的数据类型必须和相匹配的⾃变量的数据类型⼀致，但是，不同的名称还是可以使⽤给⼀个⾃变量和它相应的参数。
技巧：⾃变量（Arguments）和参数（Parameters）
①⾃变量是传递给⼀个⼦过程的变量，常量或表达式
②参数则只是接收值并传递给⼦过程的变量
Sub AboutUserMaster()
Dim first As String, last As String, full As String
Call GetUserName(full)
first = GetFirst(full)
last = GetLast(full)
Call DisplayLastFirst(first, last)
End Sub
Sub GetUserName(fullName As String)
fullName = InputBox("Enter first and last name:")
End Sub
Function GetFirst(fullName As String)
Dim space As Integer
space = InStr(fullName, " ")
GetFirst = Left(fullName, space - 1)
End Function
Function GetLast(fullName As String)
Dim space As Integer
调用子程序的例子
space = InStr(fullName, " ")
GetLast = Right(fullName, Len(fullName) - space)
End Function
Sub DisplayLastFirst(firstName As String, lastName As String)
MsgBox lastName & ", " & firstName
End Sub
技巧：使⽤⼦过程的好处
①维护多个⼦过程要⽐维护⼀个⼤过程要容易得多
②由⼀个⼦过程执⾏的任务可以给好⼏个过程使⽤
③每个⼦过程再放⼊主过程⾥之前就被单独测试
④多个程序员可以负责各⾃的⼦过程，这些⼦过程再构建⼀个⼤的程序

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。