VB中Doevents函数详解
Doevents函数是⼀个很好⽤的函数，但很多⼈对它的⽤法不清楚或有误解。由于我在⽹上查到⼀篇关于此函数的⽤法，并添加了⼀些内容，不敢独享，特此献出。
其中有⼀个“控时循环和变速齿轮”的内容，有点意思，感兴趣的可看⼀看。
DoEvents函数的功能是：转让控制权，以便让操作系统处理其它的事件。
问：为什么要⽤doevents?
A.在需要⽤某⼀循环处理相当耗时或者很快速的代码时，就需要⽤到它，以便⽤户能在起处理过程中能做其他事情，即程序能被控制,⽽不是⽆响应状态
B.vb6.0中多线程vb代码极度不稳定,⽽且⽆法调试，所以vb中的多线程⽤的很少(注：是指vb的代码在多线程中运⾏时不稳定)
C.timer控件可以起到后台运⾏作⽤，但其是通过事件控制,⼀是不稳定,⼆是速度太慢，如果想⽤其处理⾼速⼜耗系统的代码更本不能达到预期的效果
下⾯将其某些⽤法和难点简介如下:
(注: 1.'** 后⾯的代码表⽰如果在该处⽤了这个语句。2.例⼦中会⽤到API函数。3.以下例⼦都经vb6.0测试成功）
⼀. 基本⽤法:
1.窗体启动时如果要处理的事务太多或者⽤sleep函数暂停，造成其很久都不能出现时怎么办?
例如代码:
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)'此句写⼊模块
Private Sub Form_Load()
Show
'**DoEvents 句3
Sleep 5000
End Sub
通常容易想到在sleep前加个show，但还是不能达到预想的效果，窗体虽然出来了，但好象只达到了⼀半，如果加上第3句，将看到效果⼤不相同。
2.如果有个很耗时的循环导致程序不响应，怎么办?
例如:
Dim L As Long
For L = 1 To 1000000
'** DoEvents
Next L
如果⽆'**，在循环过程中程序⽆法处理事件，对于⽤户来说是不响应,⽆法控制的
3.想在循环中看到处理过程?
同样:
Dim L As Long
For L = 1 To 10000
'** DoEvents
Text1.Text=Cstr(l)
Next L
⽆'** 时将⽆法看到text1中的变化,⽽只在循环结束时看到最后结果
4.怎样中⽌循环?
如果有:
Private Sub Command1_Click()
Dim L As Long
Do
L = L + 1
Debug.Print L '在⽴即窗⼝中显⽰
DoEvents
Loop
End Sub
会发现当关闭窗⼝后,debug中的数据仍然在变化，说明并没结束
需要如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do While DoEvents
If IsExit = True Then Exit Do
L = L + 1
Loop
Private Sub Command2_Click()''或者在form_unload模块中等等
IsExit = True
End Sub
其中 isexit是全局变量
<>有些⼈喜欢⽤end语句来结束程序,⼩程序固然可以，但当太⼤，或者调⽤了某些特殊的api函数后可能导致预想不到的错误，如果装载了许多东西在程序结束时不处理将卸载很慢,⽽且这种做法也极不符合正规软件的要求...总之end语句⽑病很多，此不详谈，建议少使⽤甚⾄不使⽤
⼆. 其基本⽤法⼤概就这些，现在解析其中的⼀些[难点]
1.为什么还是不能结束?
代码如下:
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
IsExit = False
Do
If IsExit = True Then Exit Do '句0
DoEvents '** 句1
Text1.Text = CStr(L) '** 句2
L = L + 1
Loop
End Sub
Private Sub Form_Load()
Static N As Long
N = N + 1
MsgBox N
End Sub
Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub
运⾏结果：启动时msg显⽰1，点击command1,text1在变化，此时再点form右上⾓的⼩差(关闭窗体)，发现vb运⾏控制上的按扭并没变化，说明程序还在运⾏.如果编译成程序后运⾏，按下ctrl+del+alt也可发现它还没结束.
通过读代码，并没发现错误，怎么回事?
关键在于"句2"访问了控件的属性：
代码运⾏路径：当在doevents 时，程序释放控制权，可以接收事件消息,form-unload事件只能从此处产⽣，假设此时关闭form ,unload事件发⽣，即doevents后就运⾏unload代码，得到isexit=t，并且form卸载，代码返回到doevents 之后，运⾏句2.注意现在form 已经卸载了,text1从哪⾥来呢? 于是form重新装载，代码跳到form_load模块运⾏，所以在关闭窗体后可以看到msg 显⽰2，此模块运⾏完后再继续句2后⾯的代码，当下次循环遇到句0时退出循环
另：既然退出了循环，怎么还不能结束?
vb程序规定(其实其他的windows语⾔⼀样)：窗体卸载时并不是⽴即卸载其模块代码,⽽只先卸载窗体中的控件和⼀些属性值，程序中最后⼀个窗体卸载时才完全卸载.
在这个单窗体程序中,form卸载时因为循环的控制⽆法卸载代码，失去了卸载代码的机会，导致再也不能卸载(因为没卸载代码，所以运⾏的句2是并不会出错) 。
另：既然再次运⾏了form_load代码，怎么看不见窗体?
因为程序启动时窗体的到显⽰的消息,⽽只运⾏此模块并没有(如果在msgbox n语句前加上show，就可以看到它了)
如何解决?
通过以上分析，应该很简单，把句1 和句2调换⼀下就可以了，关键:
<；仔细分析代码是如何运⾏的，避免在form已经卸载了情况下访问控件>
2.⽤了doevents速度太慢了怎么办?
listview控件在哪里doevents的代价是速度变慢，但要程序响应⼜不得不⽤，其实doevents语句允许任何应⽤程序执⾏相关事件，⽽不仅仅是你⾃⼰的程序，所以变得很慢.
可以让它响应本程序事件动作，需要⽤到api函数GetInputState，它的声明语句为：
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Public Declare Function GetInputState Lib "user32" () As Long
例如⽤: If GetInputState() Then DoEvents '来代替doevents可使循环运⾏更快
3.既要同时响应事件⼜要控件不变化，怎么办?
例如在⼀个长的循环中向listview控件中添加记录,⽆doevents时程序⽆响应，但有它时控件⼜闪的厉害
解决办法:
a.不⼀定每次循环都doevents，可以在适当时间时才⽤,⾄少没那么闪
b.应⽤api函数 ValidateRect 功能是使指定的矩型区域⽣效，通知Windows不对指定的区域进⾏重画另:InvalidateRect 功能相反，同时需要⽤到函数 GetClientRect 取得指定对象的矩形区域应⽤*rect函数指定listview的矩形区不重画，即可避免闪烁(但还是要注意恢复重画，否则看不见了
4.控时循环和变速齿轮
请看下⾯的代码:
Option Explicit
Private Declare Function timeGetTime Lib "winmm.dll" () As Long
Dim IsExit As Boolean
Private Sub Command1_Click()
Dim L As Long
Dim Kt As Long
IsExit = False
Do
Kt = timeGetTime()
'do something
L = L + 1
Text1.Text = L
'DoEvents '句 1
While timeGetTime - Kt < 50 '句 2
'While Abs(timeGetTime - Kt) < 50 '句 3
'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4
DoEvents '句 5
Wend
'DoEvents '句 6
If IsExit Then Exit Do
Loop
End Sub
Private Sub Form_Unload(Cancel As Integer)
IsExit = True
End Sub
其中可⽤的代码(除去加"'" 号的代码)就是通常的控时循环代码
运⾏代码并不会出现错误，但在循环过程，请开启变速齿轮看看
当关闭齿轮时，将发现停⽌了，别慌，等⼀段时间它⼜会继续(这要看你设定的时间，这⾥是50毫秒，如果设定的太长将半天都没变化，这是怎么回事?
变速齿轮在启动时将hook.dll映射到你的程序地址运⾏，更改了timegettime()函数获取的时间
如果在句2和句3间插⼊debug.print timegettime,timegettime-kt 将发现，在关闭齿轮的瞬间后者变成了负值,timegettime变⼩了，所以才造成需要等很久
如果是编写游戏,⽽⽤户开了齿轮，那可就惨了
解决⽅案:
a.⽤句3代替句2，这个⽅法最简便，虽然不符实，但不会出问题，建议使⽤
b.不要句5，换⽤句6(这样就能达到效果吗?) 因为齿轮还是从doevents语句运⾏时才能插的进来，所以只要kt=timegettime 和 timegettime之间没有doevents就不会出错
ab.两种⽅法都有些⼩问题，但⽆⼤碍，有兴趣者请⾃⼰分析
5.程序怎么"死了"?
这只是⼀些⼈编写时没注意到的⼩问题，提醒⼀下:
同样⽤上⾯的代码，如果设定的时间太短，以⾄在代码运⾏到句2时已经超时了，句5将不能运⾏了，当然程序就死了哦，以防万⼀，加上句1，所以此时也只能⽤a⽅案来解决齿轮的问题了
有必要⽤句4代替句3 吗? 除⾮你设定的时间太长,⼈家想关闭你的程序要等上好半天。
在MSND上的内容：在使⽤全局数据时避免 DoEvents
当⼀个函数已通过 DoEvents 放弃控制时，可相当安全地再次调⽤函数。例如，下⼀过程将检测质数并⽤ DoEvents 语句周期地启动其它应⽤程序处理事件：
Function PrimeStatus (TestVal As Long) As Integer
Dim Lim As Integer
PrimeStatus = True
Lim = Sqr(TestVal)
For I = 2 To Lim
If TestVal Mod I = 0 Then
PrimeStatus = False
Exit For
End If
If I Mod 200 = 0 Then DoEvents
Next I
该代码中每重复 200 次就调⽤⼀次 DoEvents 语句。这样⼀来，当该环境的其余部分对事件作出响应时，只要有必要，PrimeStatus 过程就可继续计算。
考虑在调⽤ DoEvents 期间发⽣的事情。在其它窗体和应⽤程序处理事件时将暂停执⾏应⽤程序代码。这些事件之⼀有可能是⼀个按钮单击操作，它将再次启动 PrimeStatus 过程。
这将导致重新进⼊ PrimeStatus 过程的，但是，因为在函数每次出现时，堆栈都为其参数和局部变量分配了空间，所以重⼊不会引发冲突。当然，如果过多调⽤ PrimeStatus，则可能出现“溢出堆栈空间”错误。
如果 PrimeStatus 使⽤或改变模块级变量或全局数据，情况就会完全不同。此时，在 DoEvents 能够返回之前执⾏ PrimeStatus 的另⼀个实例，这将导致模块数据或全局数据的值完全不同于它们在调⽤ DoEvents 之前的值。于是，PrimeStatus 的结果将会难以预料。

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。