VBA 字符串用法
一、字符串比较：
1．解读Like运算符
Like运算符是字符串比较时经常使用的运算符，也是VBA较难掌握的运算符。
语法：
result = string Like pattern
Like 运算符的语法具有以下几个部分：
部分
描述
result
必需的；任何数值变量。
string
必需的；任何字符串表达式。
pattern
必需的；任何字符串表达式，遵循“说明”中的模式匹配约定。
如果字符串 (string) 与模式 (pattern) 匹配，结果为True，否则为False。但是如果Like两端的字符串和模式有一个为Null，则结果为Null。
VBA内建的模式匹配功能提供了丰富的字符串比较方式，在模式 (pattern) 表达式中可以使用通配符、字符列表（或字符区间）的任何组合来匹配字符串。
pattern 中的字符
符合 string 中的
?
任何单一字符
*
零个或多个字符
#
任何一个数字（0-9）
[字符列表]
字符列表中的任何一个字符
[!字符列表]
不在字符列表中的任何一个字符
其它字符(串)
与自身匹配
1). Like在字符串比较时受Option Compare语句的影响，在默认情况下（Option Compare Binary），字符比较根据内部二进制表示法（ASCII码）进行，是区分大小写的，此时 "A" Li
ke "a" 的结果为False。如果声明了Option Compare Text，则不区分大小写比较，"A" Like "a" 的结果为True。
后面的讨论假设默认情况下。
2). 如果模式中没有使用通配符（?、*、#）和字符列表，此时Like运算符等价于=（等号）运算符。下面表达式的结果相同。
s Like "AB"
s = "AB"
3). 字符列表
理解字符列表的用法是学会Like的难点
(1) 一个字符列表匹配的是字符串中的一个字符，不管字符列表中实际有多少个字符。
"A" Like [ABCDEGHIJ2345] 结果为True
"AB" Like [ABCDEGHIJ2345] 结果为False
唯一的例外是[]被看作长度为零的字符串。
问：
“一个字符列表匹配的是字符串中的一个字符，不管字符列表中实际有多少个字符。”
"A" Like [ABCDEGHIJ2345] 结果为True
"AB" Like [ABCDEGHIJ2345] 结果为False
这个不理解。
为什么 "A" Like [ABCDEGHIJ2345] 结果为True 而多一个 B 就为“False”
答：
和模式[ABCDEGHIJ2345] 匹配的字符串需符合两个条件:
1.它是有1个字符组成的字符串.因为这个模式只有一个字符列表.
2.这个字符是ABCDEGHIJ2345中的一个.
"A"符合这两个条件.所以为TRUE
"AB"不符合第1个条件.结果为FALSE
问：
"AB" 不也是包含在 ABCDEGHIJ2345 的吗？难道有两个字符以上就不能比较是否包含在另一个字符串（字符列表）里面？谢谢！
答：
如果要判断字符串是否由两个上面的字符组成:
模式为[ABCDEGHIJ2345][ABCDEGHIJ2345]
这时上面的"A"不匹配,"AB"匹配
(2) 字符列表中的单个字符，没有顺序要求，上面[ABCDEGHIJ2345]和[ACDEGHIJ2345B]
、[3ABCDEGHIJ245]...等等是一样的表达。
(3) 字符列表中一段连续的字符（称为区间，一个字符列表可以有多个区间，广义上，单个字符也可被看作一个区间），可以使用连字符（-，减号）简化表达式，如上面的表达式[ABCDEGHIJ2345]可以简化为[A-EG-J2-5]，连字符要遵循从小到大的顺序（升序），即连字符(-)右端的字符应大于左端的字符，如其中的A-E不能写成E-A，后者系统会报错。但多个区间之间没有顺序要求，这意味着[G-J2-5A-E]、[2-5G-JA-E]...等是同一表达。但下面的表达是错误的，同时也是常见的：
[A-E G-J 2-5]、[A-E,G-J,2-5]、[A-E;G-J;2-5]
也许只是一种习惯或想当然，第一个除了要求表达的ABCDEGHIJ2345外，还多加了一个空格；后面两个分别多了逗号(,)和分号(;)。
  "," Like [A-EG-J2-5] 结果为False
  "," Like [A-E,G-J,2-5] 结果为True
(4) 被中括号（[]）括起的字符列表中的字符，?、*、#不被理解为通配符，而是表示符号自身。如果要表示-（减号，连字符），可以放在列表的开头或结尾。如[ABC-]、[-ABC]。
  "3" Like "?" 结果为True
  "3" Like "[?]" 结果为False
  "?" Like "[?]" 结果为True
这一特性通常被用作特殊字符的表示，例如，除了通配符外， 左括号 ([)等特殊字符都可以将它们用方括号括起来。要注意的是，也不能在一个组内使用右括号 (]) 与自身匹配，但在组外可以作为个别字符使用。
(5) 在字符列表加上!(感叹号）开头，表示要匹配的是不在字符列表中的任一字符（不包括开头的!自身）。[!!]表示除了感叹号之外的任一字符。
4). 例子
下面是EXCEL/VBA帮助中举的几个Like运算符的例子，对照结果看看，如果和你想的结果都
一样，说明你已经基本掌握了Like用法。
Dim MyCheck
MyCheck = "aBBBa" Like "a*a"    ' 返回 True。
MyCheck = "F" Like "[A-Z]"    ' 返回 True。
MyCheck = "F" Like "[!A-Z]"    ' 返回 False。
MyCheck = "a2a" Like "a#a"    ' 返回 True。
MyCheck = "aM5b" Like "a[L-P]#[!c-e]"    ' 返回 True。
MyCheck = "BAT123khg" Like "B?T*"    ' 返回 True。
MyCheck = "CAT123khg" Like "B?T*"    ' 返回 False。
5). 思考题
假设有一字符串s，写出表达式，判断s是否是仅由字母组成并且以字母e（E）结尾的字符串。
Sub 主程序()
    字符串 ("aasdfasdba1E")
End Sub
Function 字符串(s As String)
Dim b As Long, a As Long
    If Mid(s, Len(s), 1) Like "[eE]" Then
      b = b + 1
      For a = 1 To Len(s) - 1
        If Mid(s, a, 1) Like "[a-zA-Z]" Then
            b = b + 1
        End If
      Next
    End If
    If b = Len(s) Then
      MsgBox "完全正确"
    End If
End Function
总是测试不成功，在这个基础上，改一改吧：
Sub 字符串()
Dim b As Long, a As Long
Dim s As String
s = "aasdfasdbaE"
'  If Mid(s, Len(s), 1) Like "[eE]" Then
  '    b = b + 1
      For a = 1 To Len(s)
        If Mid(s, a, 1) Like "[a-zA-Z]" Then
            b = b + 1
        End If
      Next
  ' End If
    If b = Len(s) And Right(s, 1) Like "[eE]" Then
      MsgBox "完全正确"
    Else
        MsgBox "No"
    End If
End Sub
2．StrComp函数
StrComp函数返回字符串比较的结果。其语法为：
StrComp(string1,string2[,compare])
其中，参数string1和strng2为必需的参数，可以是任何有效的字符串表达式。
参数Compare为可选参数，如果该参数为Null，将发生错误。
如果参数Compare设置为常数vbUseCompareOptionstring字符串转化数组或-1或忽略该参数，将使用Option Compare语句设置进行比较；
如果忽略该参数且没有设置Option Compare语句，则按二进制进行比较；
如果参数Compare设置为常数vbBinaryCompare或0，则用二进制进行比较；
如果参数 Compare设置为常数vbTextCompare或1，则按文本进行比较；
如果参数Compare设置为常数vbDatabaseCompare或 2，此时仅适用于Microsoft Access，进行基于数据库信息的比较。
StrComp函数的返回值为：
如果 String1<String2，则返回值为-1；
如果String1=String2，则返回值为0；
如果String1> String2，则返回值为1；
如果String1或String2为Null，则返回值为Null。
看看下面的示例：
Sub testStringCompare()
Dim MyStr1 As String, MyStr2 As String, MyComp1, MyComp2, MyComp3, MyComp4
MyStr1 = "ABCD"
MyStr2 = "abcd"
MyComp1 = StrComp(MyStr1, MyStr2, 1)    ' 返回 0
MyComp2 = StrComp(MyStr1, MyStr2, 0)    ' 返回 -1
MyComp3 = StrComp(MyStr1, MyStr2)    ' 返回 -1
MyComp4 = StrComp(MyStr2, MyStr1)    '返回1
MsgBox "StrComp(MyStr1, MyStr2, 1)的结果为:" & MyComp1
MsgBox "StrComp(MyStr1, MyStr2, 0)的结果为:" & MyComp2
MsgBox "StrComp(MyStr1, MyStr2)的结果为:" & MyComp3
MsgBox "StrComp(MyStr2, MyStr1)的结果为:" & MyComp4
End Sub

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。