在asp中发送邮件 表单提交到邮箱 表单发送到邮箱
1.Jmail的用法 Jmail的使用说明
<%
Dim SendStat
SendStat = Jmail("wyongzhi@gmail","Test Jmail","Just a test!","US-ASCII","text/plain")
Response.Write SendStat
%>
<%
'--------------------------------------------------------------------
Function Jmail(mailTo,mailTopic,mailBody,mailCharset,mailContentType)
'--------------------------------------------------------------------
'JMail
'--------------------------------------------------------------------
'入口参数：
'    mailTo 收件人email地址
'    mailTopic 邮件主题
'    mailBody 邮件正文(内容)
'    mailCharset 邮件字符集，例如GB2312或US-ASCII
'    mailContentType 邮件正文格式，例如text/plain或text/html
'返回值：
'    字符串，发送成功后返回OK，不成功返回错误信息
'使用方法：
'    1)设置好常量，即以Const开头的变量
'    2)使用类似如下代码发信
'Dim SendStat
'SendStat = Jmail("aa@163","测试Jmail","这是一封<br/>测试信！","GB2312","text/html")
'Response.Write SendStat
'--------------------------------------------------------------------
'***************根据需要设置常量开始*****************
Dim ConstFromNameCn,ConstFromNameEn,ConstFrom,ConstMailDomain,ConstMailServerUserName,ConstMailServerPassword
ConstFromNameCn = ""'发信人中文姓名(发中文邮件的时候使用)，例如'张三'
ConstFromNameEn = ""'发信人英文姓名(发英文邮件的时候使用)，例如'zhangsan'
ConstFrom = ""'发信人邮件地址，例如'zhangsan@163'
ConstMailDomain = ""'smtp服务器地址，例如smtp.163
ConstMailServerUserName = ""'smtp服务器的信箱登陆名，例如'zhangsan'。注意要与发信人邮件地址一致！
ConstMailServerPassword = ""'smtp服务器的信箱登陆密码
'***************根据需要设置常量结束*****************
'-----------------------------以下内容无需改动------------------------------
On Error Resume Next
Dim myJmail
Set myJmail = Server.CreateObject("JMail.Message")
myJmail.Logging = True'记录日志
myJmail.ISOEncodeHeaders = False'邮件头不使用ISO-8859-1编码
myJmail.ContentTransferEncoding = "base64"'邮件编码设为base64
myJmail.AddHeader "Priority","3"'添加邮件头,字符串常量的用法不要改动！
myJmail.AddHeader "MSMail-Priority","Normal"'添加邮件头,不要改动！
myJmail.AddHeader "Mailer","Microsoft Outlook Express 6.00.2800.1437"'添加邮件头,不要改动！
myJmail.AddHeader "MimeOLE","Produced By Microsoft MimeOLE V6.00.2800.1441"'添加邮件头,不要改动！
myJmail.Charset = mailCharset
myJmail.ContentType = mailContentType
If UCase(mailCharset) = "GB2312" Then
myJmail.FromName = ConstFromNameCn
Else
myJmail.FromName = ConstFromNameEn
End If
myJmail.From = ConstFrom
myJmail.Subject = mailTopic
myJmail.Body = mailBody
myJmail.AddRecipient mailTo
myJmail.MailDomain = ConstMailDomain
myJmail.MailServerUserName = ConstMailServerUserName
myJmail.MailServerPassword = ConstMailServerPassword
myJmail.Send ConstMailDomain
myJmail.Close
Set myJmail=nothing
If Err Then
Jmail=Err.Description
Err.Clear
Else
Jmail="OK"
End If
On Error Goto 0
End Function
'--------------------------------------------------------------------
%>

2.easyMail的用法 easymail组件的用法 easymail组件使用说明
Function SendEasyMail(Email,Topic,MailBody,TextBody)
        'on error resume next
        dim Mailsend
        set Mailsend = Server.CreateObject("easymail.Mailsend")
        Dim Tid,Un
        Un = "admin@system.mail"    '您的邮件服务器登录名，不需要密码
        Dim EI
        Set EI = server.CreateObject("easymail.Users")
        Tid = EI.Login(un)
        Set EI = Nothing
        atenew Un,Tid '邮箱账号,临时ID
        Mailsend.CharSet = "gb2312"    '编码
        Mailsend.MailName = "LeadBBS"    '发件人名
        Mailsend.EM_BackAddress = "" '邮件回复地址
        Mailsend.EM_Bcc = "" '暗送地址
        Mailsend.EM_Cc = "" '抄送地址
        Mailsend.EM_OrMailName = "" '原邮件名
        Mailsend.EM_Priority = "Normal" '邮件重要度     
        Mailsend.EM_ReadBack = false '是否读取确认,挂号信(限本系统内用户)     
        Mailsend.EM_SignNo = -1    '使用签名的序号
     
        Mailsend.EM_Subject = Topic '主题
        Mailsend.EM_Text = TextBody '内容
        Mailsend.EM_HTML_Text = MailBody 'HTML邮件内容
        Mailsend.useRichEditer = true '发送的是否为HTML格式邮件
        Mailsend.EM_TimerSend = ""    '定时发送的时间
        Mailsend.EM_To = Email '收件人地址
        Mailsend.ForwardAttString = "" '转发邮件时的原附件
        Mailsend.AddFromAttFileString = "" '添加自网络存储中的文件名
        Mailsend.SystemMessage = false '是否是系统邮件
        Mailsend.SendBackup = false '是否保存发送邮件
     
        If Mailsend.Send() = false Then
              SendEasyMail = 0
        Else
              SendEasyMail = 1
        End If
        Set Mailsend = nothing
End Function

3.无组件的用法 无组件用asp发送邮件 提交表格到指定邮箱

Function SendCDOMail(Email,Topic,TextBody)
        dim    objCDOMail
        Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
        objCDOMail.From ="mail377234@yourmail" '改为你的邮箱
        objCDOMail.To = Email
        objCDOMail.Subject = Topic
        objCDOMail.Body = TextBody
        objCDOMail.Send
        Set objCDOMail = Nothing
        SendCDOMail = 1
End Function
%>

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。