bat批处理if命令⽰例详解
⽬录
使⽤ if 命令判断上⼀条命令的退出代码
使⽤ if 命令判断⽂件是否存在
使⽤ if 命令进⾏字符串⽐较
if命令知识点(1)变量延迟扩展
if命令知识点(2)删除重复⾏
下⾯是⼀些补充
if 命令⽰例详解
if，正如它E⽂中的意思，就是“如果”的意思，⽤来进⾏条件判断。翻译过来的意思就是：如果符合某⼀条件，便执⾏后⾯的命令。
主要⽤来判断
1、两个“字符串”是否相等；
2、两个数值是⼤于、⼩于、等于，然后执⾏相应的命令。
当然还有特殊⽤法，如结合errorlevel：if errorlevel 1 echo error
或者结合defined（定义的意思）:if defined test (echo It is defined) else echo It isn't defined
使⽤ if 命令判断上⼀条命令的退出代码
左括号的左边需要有空格
else 右边需要有空格左边建议有空格
右括号、else、左括号需要放在同⼀⾏
@echo off
echo www.jb51 | findstr "jb51"
if %errorlevel% equ 0 (
echo 到指定字符串
) else (
echo 没有到指定字符串
)
pause
if errorlevel 0 判断的是 errorlevel 是否⼤于等于 0
@echo off
echo www.jb51 | findstr "jb51"
if errorlevel 1 (
echo 没有到指定字符串
) else (
echo 到指定字符串
)
pause
但把 if errorlevel 0 放在最前⾯在逻辑上是错误的
if errorlevel 0 (
echo 到指定字符串
) else if errorlevel 1 (
echo没有到指定字符串
)
使⽤ if 命令判断⽂件是否存在
不使⽤反斜线的情况下 if exist 命令⽆法直接区分⽂件和⽂件夹
判断⽂件夹的时候在最后加上反斜线
@echo off
if exist "C:\Program Files\" (
echo ⽂件夹存在
) else (
echo ⽂件夹不存在
)
pause
判断⽂件的时候先排除⽂件夹
if not 表⽰条件不成⽴的情况下执⾏命令
@echo off
if not exist "1.txt\" (
if exist "1.txt" (
echo ⽂件存在
) else (
echo ⽂件不存在
) )
pause
使⽤ if 命令进⾏字符串⽐较使⽤ == 判断两个字符串或数字是否相等
if 1 == 1 echo yes
if "a" == "a" echo yes
使⽤ /i 可以忽略字母⼤⼩写
if "a" == "A" echo yes
if /i "a" == "A" echo yes
数字⽐较不要使⽤双引号
使⽤双引号之后会变成字符串⽐较
if 2 gtr 10 echo yes
if "2" gtr "10" echo yes
⽐较操作符
equ
neq
lss
leq
gtr
geq
equal
not equal
less than
less than or equal
greater than
greater than or equal
等于
不等于
⼩于
⼩于或等于
⼤于
⼤于或等于
批处理if命令字符串⽐较和ASCII的关系
数字⼩于字母。
同⼀个字母，⼩写字母⼩于⼤写字母。
不同的字母，按照字母表中的顺序排列。扩展阅读
if命令知识点(1)变量延迟扩展
复合语句需要启⽤变量延迟扩展
xcopy 共享冲突
错误写法
@echo off
set VAR=before
if "%VAR%" == "before" (
set VAR=after
if "%VAR%" == "after" (
echo 重新赋值成功
) else (
echo 重新赋值失败
) )
pause
正确写法
@echo off
setlocal enabledelayedexpansion
set VAR=before
if "%VAR%" == "before" (
set VAR=after
if "!VAR!" == "after" (
echo 重新赋值成功
) else (
echo 重新赋值失败
) )
pause
错误写法
@echo off
for %%i in ("C:\Windows\*.exe") do (
set list=%list% %%i
)
echo %list%
pause
正确写法
@echo off
setlocal enabledelayedexpansion
for %%i in ("C:\Windows\*.exe") do (
set list=!list! %%i
)
echo %list%
pause
批处理中的变量延迟扩展、变量嵌套
if命令知识点(2)删除重复⾏使⽤ if defined 命令删除⽂本中的重复⾏
@echo off
for /f "delims=" %%i in (1.txt) do (
if not defined _%%i (
echo,%%i
set "_%%i=1"
) )
pause
C:\>
bbs
bathome
net
bathome
C:\>test.bat
bbs
bathome
net
请按任意键继续. . .
这个⽅法不适合⽤来处理⾮常⼤的⽂件，⽽且⽆法处理包含等号的⾏，参考：
下⾯是⼀些补充
⽤法⽰例：
1、检测字符串(注意，⽤if检测字符串是否相等的时候，后⾯⽤的不是“=”，⽽是“==”)：
@echo off
set "str=this is a test"
REM 检测变量%str%是否等于test，如果相等，显⽰OK，否则显⽰NO
if "%str%"=="test" (echo OK) else echo NO
pause>nul
2、检测数值：（注意，批处理中⼤于符号不能⽤：“>”,⽽⽤"gtr"，其它的也类似）
⽐较运算符⼀览：
EQU - 等于
NEQ - 不等于
LSS - ⼩于
LEQ - ⼩于或等于
GTR - ⼤于
GEQ - ⼤于或等于
检测数值 20 是否⼤于 15演⽰代码：
@echo off
set /a num1=20
set /a num2=15
if %num1% gtr %num2% echo %num1%⼤于%num2%
if %num1% EQU %num2% echo %num1%等于%num2%
if %num1% LSS %num2% echo %num1%⼩于%num2%
pause>nul
3、if结合errorlevel使⽤：
说明：环境变量errorlevel的初始值为0，当⼀些命令执⾏不成功，就会返回⼀个数值，如：1 ，2 等
IF-ERRORLEVEL
测试代码：
@ECHO OFF
XCOPY F:\test.bat D:\
IF ERRORLEVEL 1 ECHO ⽂件拷贝失败
IF ERRORLEVEL 0 ECHO 成功拷贝⽂件
如果⽂件拷贝成功，屏幕就会显⽰“成功拷贝⽂件”，否则就会显⽰“⽂件拷贝失败”。
IF ERRORLEVEL 是⽤来测试它的上⼀个DOS命令的返回值的，注意只是上⼀个命令的返回值，⽽且返回值必须依照从⼤到⼩次序顺序判断。
因此下⾯的批处理⽂件是错误的：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:\
IF ERRORLEVEL 0 ECHO 成功拷贝⽂件
IF ERRORLEVEL 1 ECHO 未到拷贝⽂件
IF ERRORLEVEL 2 ECHO ⽤户通过ctrl-c中⽌拷贝操作
IF ERRORLEVEL 3 ECHO 预置错误阻⽌⽂件拷贝操作
IF ERRORLEVEL 4 ECHO 拷贝过程中写盘错误
⽆论拷贝是否成功，后⾯的：
未到拷贝⽂件
⽤户通过ctrl-c中⽌拷贝操作
预置错误阻⽌⽂件拷贝操作
拷贝过程中写盘错误
都将显⽰出来。
附录：
以下就是⼏个常⽤命令的返回值及其代表的意义：
backup
0 备份成功
1 未到备份⽂件
2 ⽂件共享冲突阻⽌备份完成
3 ⽤户⽤ctrl-c中⽌备份
4 由于致命的错误使备份操作中⽌
diskcomp
0 盘⽐较相同
1 盘⽐较不同
2 ⽤户通过ctrl-c中⽌⽐较操作
3 由于致命的错误使⽐较操作中⽌
4 预置错误中⽌⽐较
diskcopy
0 盘拷贝操作成功
1 ⾮致命盘读/写错
2 ⽤户通过ctrl-c结束拷贝操作
3 因致命的处理错误使盘拷贝中⽌
4 预置错误阻⽌拷贝操作
format
0 格式化成功
3 ⽤户通过ctrl-c中⽌格式化处理
4 因致命的处理错误使格式化中⽌
5 在提⽰“proceed with format（y/n）?”下⽤户键⼊n结束
xcopy
0 成功拷贝⽂件
1 未到拷贝⽂件
2 ⽤户通过ctrl-c中⽌拷贝操作
4 预置错误阻⽌⽂件拷贝操作
5 拷贝过程中写盘错误
4、if还有⼀个特殊的⽤法就是可以⽤来检测某个变量是否已经被定义⽤法⽰例：
@echo off
set "str1=ok"
set "str2=no"
if defined str1 echo str1已经被定义
if defined str2 echo str2已经被定义
if defined str3 (echo str3已经被定义) else echo str3 没有被定义
pause>nul
待续....

版权声明：本站内容均来自互联网，仅供演示用，请勿用于商业和其他非法用途。如果侵犯了您的权益请与我们联系QQ:729038198，我们将在24小时内删除。