批处理Set命令详解让你理解set命令--688IT编程网

批处理Set命令详解让你理解set命令⽬录

⼀、使⽤ set 命令进⾏赋值

1、等号两边不要有空格

2、变量值包含特殊字符需⽤双引号

3、避免使⽤系统环境变量同名的⾃定义变量

4、语法可⾏但不推荐使⽤

⼆、SET /P variable=[promptString]

三、SET /A expression

四、set的通常⽤法⽰例

1、set 显⽰环境变量：

2、set 设置环境变量

3、带参数 /a的set 数值计算

4、带参数 /p 的set 等待⽤户输⼊

5、利⽤set截取字符

五、批处理Set命令详解补充篇

1、替换变量值的内容

set,E⽂翻译过来就是“设置”的意思，相当于数学⾥的“令”。

如：set X=5，就是令X=5的意思。

语法形式：

SET [variable=[string]]

SET /P variable=[promptString]

SET /A expression

⼀、使⽤ set 命令进⾏赋值

SET [variable=[string]]

1、等号两边不要有空格

正确写法

C:\>set str=ScriptHome

C:\>echo %str%

ScriptHome

错误写法

C:\>set str = ScriptHome

C:\>echo %str%

%str%

2、变量值包含特殊字符需⽤双引号

正确写法

C:\>set "str=Bat&Home"

C:\>echo "%str%"

"Bat&Home"

错误写法

C:\>set str=Bat&Home

'Home' 不是内部或外部命令，也

不是可运⾏的程序或批处理⽂件。

C:\>echo "%str%"

"Bat"

变量值设置为空可以清空变量值，实现变量初始化。

3、避免使⽤系统环境变量同名的⾃定义变量

例如：

path , date , errorlevel 等

4、语法可⾏但不推荐使⽤

使⽤连等把多个变量赋值成数字set /a x=y=100

逗号分隔把多个变量赋值成数字set /a x=1,y=2

上⾯是dos界⾯下的写法，下⾯是批处理中的写法，主意是变量

⽰例1:

显⽰所有的变量的值

@echo off

set

pause

⽰例2:

@echo off

set var=我是值

echo %var%

pause

请看 set var=我是值，这就是BAT直接在批处理中设置变量的⽅法!

set 是命令 var是变量名 =号右边的"我是值"是变量的值

在批处理中我们要引⽤这个变量就把var变量名⽤两个%(百分号)扩起来，如%var%

⼆、SET /P variable=[promptString]

有时候我们需要提供⼀个交互界⾯，让⽤户⾃⼰输⼊变量的值，然后我们在来根据这个值来做相应操作，现在我就来说说这SET的这种语法，只需要加⼀个"/P"参数就可以了! 实例1:

@echo off

set /p var=请输⼊你的名字:

echo 您的名字是:%var%

pause

set /p 是命令语法 var是变量名 =号右边的"请输⼊变量的值: "，这个是提⽰语，不是变

量的值了!

运⾏后，我们在提⽰语后⾯直接输⼊robin，就会显⽰⼀⾏您” 您的名字是:robin”

@echo off

set /p var=请输⼊变量的值:

if %var% == 1 echo 您输⼊了 1 ~_~

pause

三、SET /A expression

/A 命令⾏开关指定等号右边的字符串为被评估的数字表达式。

该表达式解析很简单并以递减的优先权顺序⽀持下列操作:

() - 分组

! ~ - - ⼀元运算符

* / % - 算数运算符

+ - - 算数运算符

<< >> - 逻辑移位

& - 按位“与”

^ - 按位“异”

| - 按位“或”

= *= /= %= += -= &= ^= |= <<= >>= - 赋值

, - 表达式分隔符

set的/A参数就是让SET可以⽀持数学符号进⾏加减等⼀些数学运算!

现在开始举例⼦介绍这些数学符号的⽤法:

看例⼦这⾥的例⼦请直接在CMD下拷贝命令运⾏，不需要保存为BAT!

set /a var=1 + 1

set /a 语法, var变量名 1 + 1 数学式⼦

拷贝运⾏后会直接显⽰⼀个2，或者运⾏完后我们输⼊echo %var%，也是⼆，这就是⼀个简单的加法运算!

set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....

set /a var=2 * 2 乘法运算

set /a var=2 / 2 除法运算

set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!

实例1：

@echo off

set /a a=1+1,b=2+1,c=3+1

echo %a% %b% %c%

实例2：

@echo off

set a=100

set b=1000

set /a c=a+b

echo the result is :%c%

pause

有时候我们需要直接在原变量进⾏加减操作就可以⽤这种语法

set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1

都是⼀样的结果，在原变量的值上在进⾏数学运算，不过这样写简单⼀点

在来⼀个:

set /a var*=2

其他都这么⽤，只要帮助⾥有这个语法!

另外还有⼀些⽤逻辑或取余操作符，这些符号，按照上⾯的使⽤⽅法会报错的

⽐如我们在CMD⾥输⼊set /a var=1 & 1 "与运算"，他并不会显⽰为1,⽽是报错,

为什么?对于这样的"逻辑或取余操作符"，我们需要把他们⽤双引号引起来，看例⼦

set /a var= 1 "&" 1 这样结果就显⽰出来了，其他逻辑或取余操作符⽤法

set /a var= 1 "^" 1 异运算

set /a var= 1 "%" 1 取模运算

set /a var= 2 "<<" 2 位左移

set /a var= 4 ">>" 2 位右移

实例3：

@echo off

set a=100

set b=1000

set /a c=a+b

set /a c= c "<<" 2

echo the result is :%c%

pause

这些符号也可以⽤&= ^= |= <<= >>= 这样的简单⽤法如

set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号

实例4：

@echo off

set p=123

title 密码是%p%

set n=1

:in

if %n% gtr 3 goto wrong

set /p a=请输⼊您需要登陆的密码:

if "%a%" equ "%p%" goto right

set/a n+=1

goto in

:right

echo 猜对了，新年快乐！

goto end

:wrong

echo 已经输过3次了，还不正确，退出！字符串截取逗号前面的

:end

pause

四、set的通常⽤法⽰例

1、set 显⽰环境变量：

如：在命令⾏下输⼊：

set 会显⽰当前所有的系统环境变量

set c 会显⽰所有的以c开头或C开头的变量（也即不区分⼤⼩写）；

set com 会显⽰所有的以com开头或COM开头的变量（不区分⼤⼩写）；

2、set 设置环境变量

⽤法⽰例：set 表达式

如：set str=ok

就是将变量str的值设置成字符串“OK”

注意：set str=ok>

这个在批处理运⾏过程中会出错，系统会提⽰：“命令语法不正确。”

原因是，因为变量str 中的值“ok>”的字符">"为⼀特殊字符，会被系统当成定向符处理，所以会运⾏出错，那如果确实要设置这样的变量str，值为 "ok>"怎么办呢？解决办法有⼆：将特殊字符转义，转义⽅法在该特殊字符前加⼀个“^”，如：set str=ok^> (这种⽅法⽐较少⽤，因为没有多少应⽤价值)

常见的解决办法，在set后⾯将整个表达式⽤引号括起来，如：set "str=>"

3、带参数 /a的set 数值计算

set的/A参数就是让SET可以⽀持数学符号进⾏加减等⼀些数学运算! ⽀持的数学运算包含（优先权递减）:

() - 分组

! ~ - - ⼀元运算符

* / % - 算数运算符

+ - - 算数运算符

<< >> - 逻辑移位

& - 按位“与”

^ - 按位“异”

| - 按位“或”

= *= /= %= += -= - 赋值

&= ^= |= <<= >>=

, - 表达式分隔符

⽤法⽰例：set /a num=2*10，这样变量num的值将变为：20

set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....

set /a var=2 * 2 乘法运算

set /a var=2 / 2 除法运算

set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!

set /a a=1+1,b=2+1,c=3+1 运⾏后会显⽰⼀个4，但我们⽤

echo %a% %b% %c%后看结果，会发现其他数学运算也有效果!，这就是"⽃"号的

作⽤!

有时候我们需要直接在原变量进⾏加减操作就可以⽤这种语法

set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1

都是⼀样的结果。

对于"逻辑或取余操作符"，我们需要把他们⽤双引号引起来，看例⼦

set /a var= 1 "&" 1 这样结果就显⽰出来了，其他逻辑或取余操作符⽤法

set /a var= 1 "+" 1 异运算

set /a var= 1 "%" 1 取模运算

set /a var= 2 "<<" 2 次⽅运算

set /a var= 4 ">>" 2 这个不太记得数学⾥的叫法....

这些符号也可以⽤&= ^= |= <<= >>= 这样的简单⽤法如

set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号

4、带参数 /p 的set 等待⽤户输⼊

windows 2000 和windows 是没有choice这个命令，choice的等待⽤户输⼊功能就要通过set /p来实现

演⽰如下：

@echo off

set /p str=请输⼊你想输⼊的字符：

echo 你输⼊的字符串为：%str%

pause>nul

set /p的特殊应⽤（set /p=<nul相当于输出字符并不带回车，利⽤这个性质，可以做出⽐较漂亮的动画），⽤法⽰例：

@echo off

for /l %%i in (1 1 70) do (

set /p=O<nul

for /l %%a in (1 1 50) do ver>nul

)

pause>nul

注：代码中⽤到了⼀句for /l %%a in (1 1 50) do ver>nul，它的⽬的是利⽤for循环运⾏某⼀命令来达到延时的⽬的。

5、利⽤set截取字符

字符串截取 set sub=%str:~x,y%

%Var:~start,len%

注意：从0开始。

例如：

@echo off

set a=www.jb51

set var=%a:~1,2%

echo %var%

pause

2、%Var:~-len%

截取倒数len位

3、%Var:~0,-len%

截取从第⼀位开始，倒数第len位结束的值。

例⼦

@echo off

set a=www.jb51

set var=%a:~0,-3%

echo %var%

pause

执⾏后，我们发现显⽰的是"www.jb51"，少了"et"

从结果分析，很容易分析出，这是把变量a的值从0位开始,

到倒数第三位之间的值全部赋予给var

看不懂的同学可以查看下⾯这个图⽚

保存下⾯的代码为test.bat运⾏查看即可。

@echo off&color 1f&rem num=15 nums=30

mode con: cols=80 lines=35

set "var=1234567890"

set "num= "

set "nums= "

rem 第⼀屏舍弃

cls&echo 第⼀屏舍弃

echo\&echo %num% var=%var%&echo\

for /l %%i in (1 1 3) do call :dan %%i

echo\

for /l %%i in (0 1 1) do call :yi %%i

echo\

for /l %%i in (0 1 2) do call :_yi %%i

echo ~ 波浪号后⾯的数字：为正数表⽰舍弃变量的前位;

echo , 逗号后⾯的数字为正数表⽰取变量的舍弃以后的前⼏位;

echo , 逗号后⾯为负数表⽰舍弃变量的后⼏位

echo\&echo\&pause&color 1e

rem 第⼆屏取

cls&echo 第⼆屏取

echo\&echo %num% var=%var%&echo\

for /l %%i in (-1 -1 -3) do call :dan %%i

echo\

for /l %%i in (-4 -1 -6) do call :er %%i

echo\

call :_er -8

echo ~ 波浪号后⾯直接跟负数表⽰取变量的后⼏位

echo , 逗号后⾯的数字为正数表⽰取变量的舍弃以后的前⼏位;

echo , 逗号后⾯为负数表⽰舍弃变量的后⼏位

echo\&echo\&pause&color 1f

rem 第三屏替换删除

cls&echo 第三屏替换删除

set "var=abc:\123\ef:g\123\456"hij"789"klm\"

echo\&echo %num%var=%var%

echo\

call :san

echo = 号左边为要替换掉的字符, 右边为需替换来的字符

echo = 号左边要替换掉的字符前⾯加个*号，代表第⼀次出现的字符及其前⾯的所有字符echo\

echo ========= 演⽰完毕 ========= 按任意键退出 ==========

pause>nul

exit

:dan

set shu=%1

if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前

if "%shu:~0,1%"=="-" set shu=%shu:~1%

set str1=%%var:~%1%%%num%

set str2=%aa%var的%ji%%shu%位%nums%

call set str3=%%var:~%1%%%num%

call echo %%str1:~0,15%% %%str2:~0,30%% %%str3:~0,15%%

goto :eof

:yi

set shu=%1

if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前

for /l %%i in (1 1 3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=%aa%var的%ji%%shu%位之后取%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,26%% %%str3:~0,15%%

if %%i==3 echo\

)

goto :eof

:_yi

for /l %%i in (-1 -1 -3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=舍弃var的前%1位和%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,28%% %%str3:~0,15%%

if %%i==-3 echo\

)

goto :eof

:er

set sss=%1

set sss=%sss:~1%

for /l %%i in (1 1 3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=从var的倒数%sss%位开始取%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,24%% %%str3:~0,15%%

if %%i==3 echo\

)

goto :eof

:_er

set sss=%1

set sss=%sss:~1%

for /l %%i in (-1 -1 -3) do (

set str1=%%var:~%1,%%i%%%num%

set str2=从var的倒数%sss%位开始并舍弃最后%%i位%nums%

call set str3=%%var:~%1,%%i%%%num%

call echo %%str1:~0,15%% %%str2:~0,20%% %%str3:~0,15%%

if %%i==-3 echo\

)

goto :eof

:san

set str1=%%var:"=%%%num%

set str2=删除var中的所有^"号%num%

set str3=%var:"=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

set str1=%%var:\=%%%num%

set str2=删除var中的所有\号%num%

set str3=%var:\=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

set str1=%%var::=%%%num%

set str2=删除var中的所有：号%num%

set str3=%var::=%%nums%

call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%

echo\

set str1=%%var:"=好%%%num%

set str2=替换var中的所有^"号为好字%num%

set str3=%var:"=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

set str1=%%var:\=好%%%num%

set str2=替换var中的所有\号为好字%num%

set str3=%var:\=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

set str1=%%var::=好%%%num%

set str2=替换var中的所有：号为好字%num%

set str3=%var::=好%%nums%

call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%

echo\

set str1=%%var:*"=%%%num%

set str3=%var:*"=%%nums%

echo 删除var中的第⼀次出现的^"号及其前⾯的所有字符